BlitzBasic Code Base

Try my new website: www.urcho.com - the new SIMPLE social network

demo

[back]

Author: joe59 | Viewed: 742 times | Language: BlitzBasic 3D | Category: Oldskool demos

AppTitle "Ennuyé samedi soir"

;placez le mode graphique et la chargé dans tous les graphiques

Graphics 640,480,16,0
SetBuffer BackBuffer()

chars = LoadImage("gfx - chars.bmp")
ball = LoadImage("gfx - ball.bmp")
char_bit = CreateImage(4,32)

MidHandle ball

; randomisez

SeedRnd MilliSecs()

; obscurcissez quelques tables de consultation

Dim qcos#(720),qsin#(720),star(50,3,2)

For count = 0 To 720
	qcos#(count) = Cos(count)
	qsin#(count) = Sin(count)
Next

For count = 1 To 50
	star(count,1,1) = Rand(0,639)
	star(count,1,2) = Rand(0,414)
	star(count,2,1) = Rand(0,639)
	star(count,2,2) = Rand(0,414)
	star(count,3,1) = Rand(0,639)
	star(count,3,2) = Rand(0,414)
Next

; écrivez votre texte ici

scroll$ = ""
scroll$ = scroll$ + "                     "
scroll$ = scroll$ + "WOOOOHOOOOO MA PREMIERE DEMONSTRATION SUR LE BLITZ VRAIMENT CELA  MA VRAIMENT  TRANSFORMER EN DEMONSTRATION DU COUT JE ME SUIS ENNUYE UN SAMEDI   "
scroll$ = scroll$ + "SOIR DECIDE POUR DONNER DES COUPS DE MARTEAU LOIN ET FAIRE UN VIEUX STYLE SINUS D AMIGA SCROLLER ALORS J AI JUSTE AJOUTE UN PEU PLUS DE CHOSES    "
scroll$ = scroll$ + "J USQU A CE QUE JAI DECIDE DE L APPELER DES CREDITS DE DEMONSTRATION POUR LA CODIFICATION VONT CHEZ MOI CUBE ET DES CREDITS POUR LA FONTE GFX ET LE REFLET   "
scroll$ = scroll$ + "LA MUSIQUE VIENT CHEZ QUELQU UN D AUTRE SI JE SAVAIS QUI LES A FAITS JE DIRAIS MOI MAIS  "
scroll$ = scroll$ + "DONC JE RETOURNE BIEN TOUS POUR MAINTENANT COMME J AIME DE TAPER ICI AINSI   "
scroll$ = scroll$ + "J ESPERE QUE CETTE PETITE DEMONSTRATION N ETAIT PAS TROP ENNUYEUSE POUR VOUS POUR REGARDER  "
scroll$ = scroll$ + "BON A PLUS TARD BIEN ERRRMMMMM SI VOUS VOUS INTERESSEZ SUR LA DEMO DEMANDEZ LE SUR BLTTZCODEBASE POUR CON VOUS EN DONNE VOILA CEST UNE DEMO INTRO     "
scroll$ = scroll$ + "                     "

; placez les variables à 0

sinus_qsin = 0
start_sinus_qsin = 0

wave_qsin = 0
start_wave_qsin = 0

ball_qsin = 0
start_ball_qsin = 0

ball_qcos = 0
start_ball_qcos = 0
ball_offset = 0

char_pos = 0
off_set = 0

; oui, OUI. une variable avec une valeur.... réjouissez-vous : D

next_char = 1

; pause pendant un moment court
Delay 2500

; jouez de la musique. aaawww

music = PlayMusic("music - brillsmurf.mod")

; <ESC> pour sortir quand vous vous ennuyez avec lui

While Not KeyHit(1)
	Cls

; simple tenez le premier rôle le champ… ouais, c'est aussi facile qu'il obtient

For count = 1 To 50
		For count2 = 1 To 3
			star(count,count2,1) = star(count,count2,1) + (4 - count2)
			If star(count,count2,1) > 639 Then star(count,count2,1) = 0
		Next

LockBuffer
		WritePixelFast star(count,1,1),star(count,1,2),(255 Or (255 Shl 8) Or (255 Shl 16) Or (255 Shl 24))
		WritePixelFast star(count,2,1),star(count,2,2),(155 Or (155 Shl 8) Or (155 Shl 16) Or (155 Shl 24))
		WritePixelFast star(count,3,1),star(count,3,2),(55 Or (55 Shl 8) Or (55 Shl 16) Or (55 Shl 24))
		UnlockBuffer
	Next

; boules de rotation… les boules partout,

start_ball_qsin = ball_qsin
	start_ball_qcos = ball_qcos

For count = 0 To 359 Step 18
		point = count + ball_offset
		DrawImage ball,320 + (qcos#(ball_qcos) * 100) + (qcos#(point) * 190), 220 + (qsin#(point) * qsin#(ball_qsin) * 190)
	Next

ball_qsin = start_ball_qsin + 2
	If ball_qsin >=360 Then ball_qsin = 0
	ball_qcos = start_ball_qcos + 3
	If ball_qcos >=360 Then ball_qcos = 0
	ball_offset = ball_offset + 2
	If ball_offset = 360 Then ball_offset = 0

; le défilement des textes

start_sinus_qsin = sinus_qsin
	on_char = next_char

character$ = Mid$(scroll$,on_char,1)
	If character$ > " " Then
		which_char = Asc(character$) - 65
	Else
		which_char = 26
	End If

char_pos = offset

For x = 0 To 639 Step 4
		CopyRect (which_char * 32) + char_pos,0,4,32,0,0,ImageBuffer(chars),ImageBuffer(char_bit)
		DrawImage char_bit,x,318 + (qsin#(sinus_qsin) * 100)

char_pos = char_pos + 4
		If char_pos >= 32 Then
			char_pos = 0

on_char = on_char + 1

character$ = Mid$(scroll$,on_char,1)
			If character$ > " " Then
				which_char = Asc(character$) - 65
			Else
				which_char = 26
			End If
		End If

sinus_qsin = sinus_qsin + 1
		If sinus_qsin = 360 Then sinus_qsin = 0
	Next

sinus_qsin = start_sinus_qsin + 3
	If sinus_qsin >= 360 Then sinus_qsin = 0

offset = offset + 4
	If offset = 32 Then
		offset = 0
		next_char = next_char + 1
		If next_char > Len(scroll$) Then next_char = 1
	End If

; effet de l'eau d'ondulation

start_wave_qsin = wave_qsin

For y = 415 To 447 Step 2
		CopyRect 0,y,639,1,(qsin(wave_qsin) * 10),479 - (y - 415)
		wave_qsin = wave_qsin + 15
		If wave_qsin >= 360 Then wave_qsin = 0
	Next

wave_qsin = start_wave_qsin + 15
	If wave_qsin >= 360 Then wave_qsin = 0

; où est ma musique ? ...
	If Not ChannelPlaying(music) Then music = PlayMusic("music - brillsmurf.mod")

; renversez, répétez, renversez la répétition, chiquenaude .....
	Flip
Wend

End

Author Comments:

inconnu